Send CPU load from BAT file in Windows

@echo off
setlocal enabledelayedexpansion
rem === Set your API_KEY below ==========================
set API_KEY=6ruyjBszNj1RvHLNGPDRjT
rem =====================================================

for /f "usebackq tokens=* delims=" %%A in (`curl -s https://gazer.cloud/view_url_by_api_key/%API_KEY%`) do set VIEW_URL=%%A
echo =====================================================
echo View URL:
echo %VIEW_URL%
echo =====================================================
echo Press Ctrl+C to stop sending data.
echo.

:loop

for /f "tokens=* delims=" %%A in ('wmic cpu get loadpercentage ^| findstr /r "^[0-9]"') do (
    set CPU_LOAD_RAW=%%A
)

set CPU_LOAD=%CPU_LOAD_RAW: =%
echo CPU Load: !CPU_LOAD!%%

set VALUE_Main=!CPU_LOAD!
set VALUE_Main_Name="CPU Load"
set VALUE_Main_UOM=%%25

echo Sending time: !VALUE_Main!
set CMD=curl -s -X POST "https://gazer.cloud/set/%API_KEY%"
set CMD=!CMD! -d "/=!VALUE_Main!"
set CMD=!CMD! -d "/_name=!VALUE_Main_Name!"
set CMD=!CMD! -d "/_uom=!VALUE_Main_UOM!"
!CMD!
	
timeout /t 1 >nul
goto loop